{-# LANGUAGE BlockArguments #-}
{-# LANGUAGE DuplicateRecordFields #-}
{-# LANGUAGE ForeignFunctionInterface #-}
{-# LANGUAGE LambdaCase #-}
{-# LANGUAGE OverloadedRecordDot #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE PartialTypeSignatures #-}

-- TODO Edit issues.
--
-- I would like to edit issues from the command line.
--
-- `anissue edit @id` should bring up the issue inside `$EDITOR`, updating the issue with any changes made within `$EDITOR`.
--
-- Comment markers should be stripped, and the file format should be Markdown. Issue markers could be stripped.
--
-- I am personally anticipating that this is used most frequently in response to `anissue show @id`. So, maybe `anissue show @id --edit` should be a synonym?
-- Rationale: the latter is typing `<UP> --edit<CR>`. The former, after show, is typing `<UP><ESC>^wcwedit<CR>`, the former obviously being more palatable.

-- TODO Tag improvements (OR-filtering).
--
-- Currently it is not possible to filter for an issue satisfying one filter or another. We could add the following syntax allowing it:
--
-- `--filter '(@assigned aforemny) OR (@due 2023-10-4)'`
-- @topic tags

-- TODO Tag improvements (globbing).
--
-- I would like to filter `--filter '@assigned *@posteo.de'`.
-- @topic tags

-- TODO Tag improvements (priorities)
--
-- I would like anissue to support priorities when filtering. Let's for a first implementation say that priorities are represented by an integer-values `@priority` tag on an issue. The `--filter` can be extended for filtering integer-valued tags, and the following syntax:
--
-- - `--filter '@priority >1'`, `--filter '@priority <1`
-- - `--filter '@priority >=1'`, `--filter '@priority <=1`
--
-- At some later point, we can configure `high`, `medium`, `low` to mean
-- `1,2,3`, `4,5,6`, `7,8,9` respectively.
--
-- Issues having a `@priority` tag whose value is not an integer should be regarded not matching the filter.
-- @topic tags

-- TODO Tag improvements (dates).
--
-- I would like anissue to support due dates when filtering. Let's for a first implementation add the following filter syntax:
--
-- `--filter '@due 2023-10-04'` for all issues that are marked `@due 2023-10-04` or with an earlier `@due` date.
--
-- Issues having a `@due` tag whose value does not follow that date format precisely should be regarded not matching the filter.
-- @topic tags

-- TODO Add support for ammendments
--
-- The user can ammend more information to an issue which is located at
-- a different place by referencing the issue's id.  Example:
--
-- ```bash
-- #!/usr/bin/env bash
--
-- set -efu
--
-- ls -al
-- # TODO Original issue
-- #
-- # @id original-issue
--
-- ls
-- # @original-issue more information on the issue
-- ```

module Main where

import Control.Exception (Exception, catch, handle, throw, throwIO)
import Data.Aeson qualified as A
import Data.ByteString.Lazy qualified as L
import Data.ByteString.Lazy.Char8 qualified as L8
import Data.List (find, intercalate)
import Data.Maybe (catMaybes, fromMaybe)
import Data.String qualified as String
import Data.Text qualified as T
import Issue (Issue (..))
import Issue qualified as I
import Issue.Filter (Filter)
import Issue.Filter qualified as I
import Issue.Tag qualified as I
import Options.Applicative ((<**>))
import Options.Applicative qualified as O
import Prettyprinter qualified as P
import Prettyprinter.Render.Terminal qualified as P
import System.Exit (ExitCode (ExitFailure), exitWith)
import System.FilePath qualified as F
import System.Process.Typed qualified as P
import Text.Printf
import TreeGrepper.Match qualified as G
import TreeGrepper.Result qualified as G
import Prelude hiding (id)

data Command
  = List
      { files :: [String],
        filters :: [Filter],
        internalTags :: Bool
      }
  | Show
      { id :: String,
        width :: Maybe Int
      }
  deriving (Show)

cmd :: O.Parser Command
cmd =
  O.hsubparser . mconcat $
    [ O.command "list" . O.info listCmd $
        O.progDesc "List all issues",
      O.command "show" . O.info showCmd $
        O.progDesc "Show details of all issues"
    ]

listCmd :: O.Parser Command
listCmd =
  List
    <$> filesArg
    <*> I.filterArg
    <*> internalTagsFlag

showCmd :: O.Parser Command
showCmd =
  Show
    <$> idArg
    <*> widthOption

filesArg :: O.Parser [String]
filesArg = O.many (O.strArgument (O.metavar "FILE" <> O.action "file"))

internalTagsFlag :: O.Parser Bool
internalTagsFlag =
  O.switch
    ( O.long "internal-tags"
        <> O.help "Whether to display internal tags."
    )

idArg :: O.Parser String
idArg =
  O.strArgument
    ( O.metavar "ID"
        <> O.completer
          ( O.listIOCompleter $
              catMaybes . map I.id <$> listIssues [] []
          )
    )

widthOption :: O.Parser (Maybe Int)
widthOption =
  O.optional
    ( O.option
        O.auto
        ( O.long "width"
            <> O.short 'w'
            <> O.metavar "INT"
            <> O.help "Wheather to insert line breaks after at most that many characters."
        )
    )

die :: String -> IO a
die s = do
  printf "error: %s\n" s
  exitWith (ExitFailure 1)

main :: IO ()
main = do
  O.execParser (O.info (cmd <**> O.helper) O.idm) >>= \case
    List {filters, files, internalTags} -> do
      issues <- listIssues filters files
      putDoc . P.vsep $
        map
          ( \issue ->
              P.hsep
                ( concat
                    [ [P.annotate P.bold (P.pretty issue.title)],
                      map
                        ( \(I.Tag k v) ->
                            P.annotate (P.colorDull P.Yellow) $
                              P.pretty ("@" `T.append` k `T.append` " " `T.append` v)
                        )
                        ( issue.tags
                            ++ if internalTags then issue.internalTags else []
                        )
                    ]
                )
          )
          issues
    Show {id, width} -> do
      issues <- listIssues [] []
      case find ((==) (Just id) . I.id) issues of
        Nothing -> die (printf "no issue with id `%s'\n" id)
        Just issue -> do
          putDoc $
            P.annotate (P.color P.Green) $
              P.pretty $
                issue.file
                  ++ ":"
                  ++ show issue.start.row
                  ++ "\n\n"
          sh_
            ( P.setStdin
                ( String.fromString
                    ( "# "
                        ++ T.unpack issue.title
                        ++ "\n\n"
                        ++ fromMaybe "" (fmap T.unpack issue.description)
                    )
                )
                ( case width of
                    Nothing ->
                      "mdcat --local"
                    Just width' ->
                      String.fromString (printf "mdcat --columns %d --local" width')
                )
            )
          putDoc $
            P.pretty $
              "\n@file "
                ++ issue.file
                ++ "\n@row "
                ++ show issue.start.row
                ++ "\n"

putDoc :: P.Doc P.AnsiStyle -> IO ()
putDoc doc = do
  isTty <- (== 1) <$> c_isatty 1
  P.putDoc . (if isTty then (\x -> x) else P.unAnnotate) $ doc

foreign import ccall "unistd.h isatty" c_isatty :: Int -> IO Int

data UnknownFileExtension = UnknownFileExtension
  { extension :: String
  }
  deriving (Show)

instance Exception UnknownFileExtension

data InvalidTreeGrepperResult = InvalidTreeGrepperResult
  { error :: String
  }
  deriving (Show)

instance Exception InvalidTreeGrepperResult

listIssues :: [Filter] -> [FilePath] -> IO [Issue]
listIssues filters files =
  filter (I.applyFilter filters) . concat
    <$> catch
      ( mapM (handle forgetGetIssuesExceptions . getIssues)
          =<< getFiles files
      )
      (\(InvalidTreeGrepperResult e) -> die e)
  where
    forgetGetIssuesExceptions :: UnknownFileExtension -> IO [a]
    forgetGetIssuesExceptions _ = pure []

getIssues :: FilePath -> IO [Issue]
getIssues filename =
  let extension = F.takeExtension filename
      treeGrepperLanguage =
        -- TODO Add support for all tree-grepper supported files
        --
        -- tree-grepper supported files can be listed through `tree-grepper
        -- --languages`.
        case extension of
          ".elm" -> "elm"
          ".hs" -> "haskell"
          ".nix" -> "nix"
          ".sh" -> "sh"
          _ -> throw (UnknownFileExtension extension)
      treeGrepperQuery =
        case extension of
          ".elm" -> "([(line_comment) (block_comment)])"
          ".hs" -> "(comment)"
          ".nix" -> "(comment)"
          ".sh" -> "(comment)"
          _ -> throw (UnknownFileExtension extension)
      decode raw =
        case A.eitherDecode raw of
          Left e -> throw (InvalidTreeGrepperResult e)
          Right treeGrepperResult -> treeGrepperResult
   in catMaybes
        . map (uncurry I.fromMatch)
        . concatMap (\result -> map ((,) result) result.matches)
        . map fixTreeGrepper
        . decode
        <$> sh
          ( String.fromString
              ( printf
                  "tree-grepper --query %s %s --format json %s"
                  (quote treeGrepperLanguage)
                  (quote treeGrepperQuery)
                  (quote filename)
              )
          )

data ProcessException = ProcessException String ExitCode L.ByteString
  deriving (Show)

instance Exception ProcessException

sh :: P.ProcessConfig stdin stdoutIgnored stderr -> IO L.ByteString
sh proc = do
  (exitCode, out, err) <- P.readProcess proc
  if exitCode == P.ExitSuccess
    then pure out
    else throwIO $ ProcessException (show proc) exitCode err

sh_ :: P.ProcessConfig stdin stdoutIgnored stderr -> IO ()
sh_ proc = do
  (exitCode, err) <- P.readProcessStderr proc
  if exitCode == P.ExitSuccess
    then pure ()
    else throwIO $ ProcessException (show proc) exitCode err

fixTreeGrepper :: G.Result -> G.Result
fixTreeGrepper treeGrepperResult =
  treeGrepperResult {G.matches = G.merge treeGrepperResult.matches}

getFiles :: [String] -> IO [FilePath]
getFiles files =
  lines . L8.unpack
    <$> sh
      ( String.fromString
          ( (printf "git ls-files --cached --exclude-standard --other%s")
              ( case files of
                  [] -> ""
                  _ -> " -- " ++ intercalate " " (map quote files)
              )
          )
      )
  where

quote :: String -> String
quote s = "'" ++ escape s ++ "'"
  where
    escape [] = []
    escape ('\'' : cs) = '\\' : '\'' : escape cs
    escape (c : cs) = c : escape cs