module Patch
  ( Patch,
    parse,
  )
where

import Control.Exception (throw)
import Data.Text qualified as T
import Exception qualified as E
import Render ((<<<))
import Render qualified as P
import Text.Diff.Parse qualified as D
import Text.Diff.Parse.Types qualified as D

newtype Patch = Patch
  { fileDeltas :: D.FileDeltas
  }
  deriving (Show)

parse :: T.Text -> Patch
parse = either (throw . E.InvalidDiff) Patch . D.parseDiff

instance P.Render Patch where
  render = P.render . P.Detailed

instance P.Render (P.Detailed Patch) where
  render (P.Detailed (Patch {..})) =
    P.vsep $ map prettyFileDelta fileDeltas
    where
      prettyFileDelta (D.FileDelta {..}) = prettyContent fileDeltaContent
      prettyContent D.Binary = P.emptyDoc
      prettyContent (D.Hunks hunks) = P.vsep (map prettyHunk hunks)
      prettyHunk (D.Hunk {..}) = P.vsep $ map prettyLine hunkLines
      prettyLine (D.Line {..}) =
        case lineAnnotation of
          D.Added -> P.styled [P.color P.Green] $ P.plus @P.AnsiStyle <<< lineContent
          D.Removed -> P.styled [P.color P.Red] $ P.minus @P.AnsiStyle <<< lineContent
          D.Context -> P.styled [P.color P.White] $ P.space @P.AnsiStyle <<< lineContent