path: root/app/Main.hs

{-# LANGUAGE DuplicateRecordFields #-}
{-# LANGUAGE OverloadedRecordDot #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE PartialTypeSignatures #-}

-- TODO Add support for ammendments
--
-- The user can ammend more information to an issue which is located at
-- a different place by referencing the issue's id.  Example:
--
-- ```bash
-- #!/usr/bin/env bash
--
-- set -efu
--
-- ls -al
-- # TODO Original issue
-- #
-- # @id original-issue
--
-- ls
-- # @original-issue more information on the issue
-- ```

-- TODO Only one issue per comment block
--
-- Only the first TODO/FIXME inside a comment block should be considered
-- as the start of an issue.

-- TODO Add support for other keywords
--
-- Additionally to TODO, also FIXME should start an issue.  There might
-- be more interesting keywords.

-- TODO Add filter by tags
--
-- Users can filter issues for tags with the option -t/--tag @tag.
--
-- @assigned kirchner@posteo.de

-- TODO Generate and show hash for each issue

module Main where

import Control.Exception (Exception, catch, throw, throwIO)
import Data.Aeson qualified as A
import Data.ByteString.Lazy qualified as L
import Data.ByteString.Lazy.Char8 qualified as L8
import Data.List (intercalate)
import Data.Maybe (catMaybes)
import Data.Maybe qualified as Maybe
import Data.String qualified as String
import Data.Text qualified as T
import Data.Text.IO qualified as T
import Issue (Issue (..))
import Issue qualified as I
import Issue.Tag qualified as I
import Options.Applicative ((<**>))
import Options.Applicative qualified as O
import System.Exit (ExitCode (ExitFailure), exitWith)
import System.FilePath qualified as F
import System.IO (hPutStrLn, stderr)
import System.Process.Typed qualified as P
import Text.Printf
import TreeGrepper.Match qualified as G
import TreeGrepper.Result qualified as G

data Options = Options
  { optCommand :: Command
  }
  deriving (Show)

data Command
  = List
      { files :: [String]
      }
  | Show
      { files :: [String]
      }
  deriving (Show)

commandParser :: O.Parser Command
commandParser =
  O.hsubparser
    ( O.command "list" (O.info listCommandParser (O.progDesc "List all issues"))
        <> O.command "show" (O.info showCommandParser (O.progDesc "Show details of all issues"))
    )

optionsParser :: O.Parser Options
optionsParser = Options <$> commandParser

listCommandParser :: O.Parser Command
listCommandParser = List <$> filesArg

showCommandParser :: O.Parser Command
showCommandParser = Show <$> filesArg

filesArg :: O.Parser [String]
filesArg = O.many (O.strArgument (O.metavar "FILE"))

main :: IO ()
main = do
  options <- O.execParser (O.info (commandParser <**> O.helper) O.idm)
  let files
        | opts@(List {}) <- options = opts.files
        | opts@(Show {}) <- options = opts.files
  filePaths <- getFiles files
  issues <-
    catch
      ( fmap Maybe.catMaybes $
          mapM
            (\filename -> catch (fmap Just (getIssues filename)) (forgetGetIssuesExceptions))
            filePaths
      )
      ( \(InvalidTreeGrepperResult e) ->
          do
            hPutStrLn stderr e
            exitWith (ExitFailure 1)
      )
  case options of
    List _ -> mapM_ listMatches $ concat issues
    Show _ -> mapM_ showMatches $ concat issues

showMatches :: Issue -> IO ()
showMatches issue = do
  T.putStrLn issue.title
  T.putStrLn ""
  T.putStrLn issue.description

listMatches :: Issue -> IO ()
listMatches issue =
  printf
    "%s%s\n"
    issue.title
    ( if null issue.tags
        then ""
        else
          T.append " " . T.intercalate " " $
            map (\(I.Tag k v) -> T.intercalate ":" [k, v]) issue.tags
    )

data UnknownFileExtension = UnknownFileExtension
  { extension :: String
  }
  deriving (Show)

instance Exception UnknownFileExtension

data InvalidTreeGrepperResult = InvalidTreeGrepperResult
  { error :: String
  }
  deriving (Show)

instance Exception InvalidTreeGrepperResult

forgetGetIssuesExceptions :: UnknownFileExtension -> IO (Maybe a)
forgetGetIssuesExceptions _ = pure Nothing

getIssues :: FilePath -> IO [Issue]
getIssues filename =
  let extension = F.takeExtension filename
      treeGrepperLanguage =
        -- TODO Add support for all tree-grepper supported files
        --
        -- tree-grepper supported files can be listed through `tree-grepper
        -- --languages`.
        case extension of
          ".elm" -> "elm"
          ".hs" -> "haskell"
          ".nix" -> "nix"
          ".sh" -> "sh"
          _ -> throw (UnknownFileExtension extension)
      treeGrepperQuery =
        case extension of
          ".elm" -> "([(line_comment) (block_comment)])"
          ".hs" -> "(comment)"
          ".nix" -> "(comment)"
          ".sh" -> "(comment)"
          _ -> throw (UnknownFileExtension extension)
      decode raw =
        case A.eitherDecode raw of
          Left e -> throw (InvalidTreeGrepperResult e)
          Right treeGrepperResult -> treeGrepperResult
   in catMaybes
        . map (uncurry I.fromMatch)
        . concatMap (\result -> map ((,) result) result.matches)
        . map fixTreeGrepper
        . decode
        <$> sh
          ( String.fromString
              ( printf
                  "tree-grepper --query %s %s --format json %s"
                  (quote treeGrepperLanguage)
                  (quote treeGrepperQuery)
                  (quote filename)
              )
          )

data ProcessException = ProcessException String ExitCode L.ByteString
  deriving (Show)

instance Exception ProcessException

sh :: P.ProcessConfig stdin stdoutIgnored stderr -> IO L.ByteString
sh proc = do
  (exitCode, out, err) <- P.readProcess proc
  if exitCode == P.ExitSuccess
    then pure out
    else throwIO $ ProcessException (show proc) exitCode err

fixTreeGrepper :: G.Result -> G.Result
fixTreeGrepper treeGrepperResult =
  treeGrepperResult {G.matches = G.merge treeGrepperResult.matches}

getFiles :: [String] -> IO [FilePath]
getFiles files =
  lines . L8.unpack
    <$> sh
      ( String.fromString
          ( (printf "git ls-files --cached --exclude-standard --other%s")
              ( case files of
                  [] -> ""
                  _ -> " -- " ++ intercalate " " (map quote files)
              )
          )
      )
  where

quote :: String -> String
quote s = "'" ++ escape s ++ "'"
  where
    escape [] = []
    escape ('\'' : cs) = '\\' : '\'' : escape cs
    escape (c : cs) = c : escape cs